 ## Mplus code for mediation, moderation, and moderated mediation models

Model 91: 2 or more mediators, in series, 1 moderator moderating path between mediators

Example Variables: 1 predictor X, 2 mediators M1 and M2, 1 moderator W, 1 outcome Y

Preliminary notes:

The code below assumes that

• The primary IV (variable X) is continuous or dichotomous
• Any moderators (variables W, V, Q, Z) are continuous, though the only adaptation required to handle dichotomous moderators is in the MODEL CONSTRAINT: and loop plot code - an example of how to do this is given in model 1b. Handling categorical moderators with > 2 categories is demonstrated in model 1d.
• Any mediators (variable M, or M1, M2, etc.) are continuous and satisfy the assumptions of standard multiple regression. An example of how to handle a dichotomous mediator is given in model 4c.
• The DV (variable Y) is continuous and satisfies the assumptions of standard multiple regression. An example of how to handle a dichotomous DV is given in model 1e (i.e. a moderated logistic regression) and in model 4d (i.e. an indirect effect in a logistic regression).

Model Diagram: Statistical Diagram: Model Equation(s):

Y = b0 + b1M1 + b2M2 + c'X
M1 = a01 + a1X
M2 = a02 + a2X + d1M1 + d2W + d3M1W

Algebra to calculate total, indirect and/or conditional effects by writing model as Y = a + bX:

Y = b0 + b1M1 + b2M2 + c'X
M1 = a01 + a1X
M2 = a02 + a2X + d1M1 + d2W + d3M1W

Hence... substituting in equations for M1 and M2

Y = b0 + b1(a01 + a1X) + b2(a02 + a2X + d1(a01 + a1X) + d2W + d3(a01 + a1X)W) + c'X

Hence... multiplying out brackets

Y = b0 + a01b1 + a1b1X + a02b2 + a2b2X + a01d1b2 + a1d1b2X + d2b2W + a01d3b2W + a1d3b2XW + c'X

Hence... grouping terms into form Y = a + bX

Y = (b0 + a01b1 + a02b2 + a01d1b2 + d2b2W + a01d3b2W) + (a1b1 + a1d1b2 + a2b2 + a1d3b2W + c')X

Hence...

Three indirect effects of X on Y:

a1b1, a2b2, a1b2(d1 + d3W)

One direct effect of X on Y:

c'

Mplus code for the model:

! Predictor variable - X
! Mediator variable(s) � M1, M2
! Moderator variable(s) - W
! Outcome variable - Y

USEVARIABLES = X M1 M2 W Y M1W;

! Create interaction term
! Note that it has to be placed at end of USEVARIABLES subcommand above

DEFINE:
M1W = M1*W;

ANALYSIS:
TYPE = GENERAL;
ESTIMATOR = ML;
BOOTSTRAP = 10000;

! In model statement name each path using parentheses

MODEL:
Y ON M1 (b1);
Y ON M2 (b2);

Y ON X (cdash);   ! direct effect of X on Y

M1 ON X (a1);
M2 ON X (a2);
M2 ON M1 (d1);
M2 ON W (d2);
M2 ON M1W (d3);

! Use model constraint subcommand to test simple slopes
! You need to pick low, medium and high moderator values,
! for example, of 1 SD below mean, mean, 1 SD above mean
! Also calc total effects at lo, med, hi values of moderator

MODEL CONSTRAINT:
NEW(LOW_W MED_W HIGH_W
a1b1 a2b2
LWa1d1b2 MWa1d1b2 HWa1d1b2
IMM
TOT_LOWW TOT_MEDW TOT_HIW);

LOW_W = #LOWW;   ! replace #LOWW in the code with your chosen low value of W
MED_W = #MEDW;   ! replace #MEDW in the code with your chosen medium value of W
HIGH_W = #HIGHW;   ! replace #HIGHW in the code with your chosen high value of W

! Now calc indirect and total effects for each value of W
a1b1 = a1*b1;   ! Specific indirect effect of X on Y via M1 only
a2b2 = a2*b2;   ! Specific indirect effect of X on Y via M2 only

! Conditional indirect effects of X on Y via M1 and M2 given values of W

LWa1d1b2 = a1*d1*b2 + a1*d3*b2*LOW_W;
MWa1d1b2 = a1*d1*b2 + a1*d3*b2*MED_W;
HWa1d1b2 = a1*d1*b2 + a1*d3*b2*HIGH_W;

! Index of Moderated Mediation

IMM = a1*d3*b2;

! Conditional total effects of X on Y given values of W

TOT_LOWW = LWa1d1b2 + a1b1 + a2b2 + cdash;
TOT_MEDW = MWa1d1b2 + a1b1 + a2b2 + cdash ;
TOT_HIW = HWa1d1b2 + a1b1 + a2b2 + cdash;

! Use loop plot to plot total effect of X on Y for low, med, high values of W
! NOTE - values of 1,5 in LOOP() statement need to be replaced by
! logical min and max limits of predictor X used in analysis

PLOT(LOMOD MEDMOD HIMOD);

LOOP(XVAL,1,5,0.1);

LOMOD = TOT_LOWW*XVAL;
MEDMOD = TOT_MEDW*XVAL;
HIMOD = TOT_HIW*XVAL;

PLOT:
TYPE = plot2;

OUTPUT:
STAND CINT(bcbootstrap);