﻿figure it out - a statistical consultancy from the Institute of Work Psychology, University of Sheffield ## Mplus code for mediation, moderation, and moderated mediation models

Model 75 (latent variable version): 1 or more mediators, in parallel if multiple (example uses 1), 2 moderators, both moderating both the IV- Mediator path and the Mediator-DV path

Example Variables: 1 latent predictor X measured by 4 observed variables X1-X4, 1 latent mediator M measured by 4 observed variables M1-M4, 2 latent moderators W and Z, each measured by sets of 4 observed variables W1-W4 and Z1-Z4 respectively, 1 latent outcome Y measured by 4 observed variables Y1-Y4

Preliminary notes:

The code below assumes that

• The latent IV (factor X) is measured by continuous observed variables X1-X4.
• Any latent moderator(s) (factors W, V, Q, Z) are measured by continuous observed variables W1-W4, Z1-Z4, V1-V4, Q1-Q4 respectively.
• Any latent mediator(s) (factor M, or factors M1, M2, etc.) are measured by continuous observed variables M1-M4 or M1_1-M1-4, M2_1-M2_4 respectively.
• The latent outcome Y is measured by continuous observed variables Y1-Y4.

Model Diagram (factor indicator variables omitted for space/clarity reasons): Statistical Diagram (factor indicator variables omitted for space/clarity reasons): Model Equation(s):

Y = b0 + b1M + b2W + b3Z + b4MW + b5MZ + c'X
M = a0 + a1X + a2W + a3Z + a4XW + a5XZ

Algebra to calculate indirect and/or conditional effects by writing model as Y = a + bX:

Y = b0 + b1M + b2W + b3Z + b4MW + b5MZ + c'X
M = a0 + a1X + a2W + a3Z + a4XW + a5XZ

Hence... substituting in equation for M

Y = b0 + b1(a0 + a1X + a2W + a3Z + a4XW + a5XZ) + b2W + b3Z + b4(a0 + a1X + a2W + a3Z + a4XW + a5XZ)W + b5(a0 + a1X + a2W + a3Z + a4XW + a5XZ)Z + c'X

Hence... multiplying out brackets

Y = b0 + a0b1 + a1b1X + a2b1W + a3b1Z + a4b1XW + a5b1XZ + b2W + b3Z + a0b4W + a1b4XW + a2b4WW + a3b4ZW + a4b4XWW + a5b4XZW + a0b5Z + a1b5XZ + a2b5WZ + a3b5ZZ + a4b5XWZ + a5b5XZZ + c'X

Hence... grouping terms into form Y = a + bX

Y = (b0 + a0b1 + a2b1W + a3b1Z + b2W + b3Z + a0b4W + a2b4WW + a3b4ZW + a0b5Z + a2b5WZ + a3b5ZZ) + (a1b1 + a4b1W + a5b1Z + a1b4W + a4b4WW + a5b4ZW + a1b5Z + a4b5WZ + a5b5ZZ + c')X

Hence...

One indirect effect(s) of X on Y, conditional on W, Z:

a1b1 + a4b1W + a5b1Z + a1b4W + a4b4WW + a5b4ZW + a1b5Z + a4b5WZ + a5b5ZZ = (a1 + a4W + a5Z)(b1 + b4W + b5Z)

One direct effect of X on Y:

c'

Mplus code for the model:

! Latent predictor variable X measured by X1-X4
! Latent mediator M measured by 4 observed variables M1-M4
! Latent moderators W and Z, each measured by sets of 4 observed variables W1-W4 and Z1-Z4 respectively
! Latent outcome variable Y measured by Y1-Y4

USEVARIABLES = X1 X2 X3 X4 M1 M2 M3 M4
W1 W2 W3 W4 Z1 Z2 Z3 Z4
Y1 Y2 Y3 Y4;

ANALYSIS:
TYPE = GENERAL RANDOM;
ESTIMATOR = ML;
ALGORITHM = INTEGRATION;

! In model statement first state measurement model
! Then create any latent interactions required
! Then state structural model naming each path and intercept using parentheses

MODEL:

! Measurement model
! This makes these factors standardised
X BY X1 X2 X3 X4;
M BY M1 M2 M3 M4;
W BY W1* W2 W3 W4;
Z BY Z1* Z2 Z3 Z4;
Y BY Y1 Y2 Y3 Y4;

W@1;   Z@1;

! Create latent interactions
MW | M XWITH W;
MZ | M XWITH Z;
XW | X XWITH W;
XZ | X XWITH Z;

! Fit structural model and name parameters
! Note that intercepts of M, Y are fixed = 0 since they are latent vars
! so no code to state and name them as parameters
Y ON M (b1);
Y ON W (b2);
Y ON Z (b3);
Y ON MW (b4);
Y ON MZ (b5);

Y ON X(cdash);

M ON X (a1);
M ON W (a2);
M ON Z (a3);
M ON XW (a4);
M ON XZ (a5);

! Use model constraint subcommand to test conditional indirect effects
! You need to pick low, medium and high moderator values for W, Z
! for example, of 1 SD below mean, mean, 1 SD above mean

! 2 moderators, 3 values for each, gives 9 combinations
! arbitrary naming convention for conditional indirect and total effects used below:
! MEV_LOQ = medium value of V and low value of Q, etc.

MODEL CONSTRAINT:
NEW(LOW_W MED_W HIGH_W LOW_Z MED_Z HIGH_Z
ILOW_LOZ IMEW_LOZ IHIW_LOZ ILOW_MEZ IMEW_MEZ IHIW_MEZ
ILOW_HIZ IMEW_HIZ IHIW_HIZ
TLOW_LOZ TMEW_LOZ THIW_LOZ TLOW_MEZ TMEW_MEZ THIW_MEZ
TLOW_HIZ TMEW_HIZ THIW_HIZ);

LOW_W = -1;   ! -1 SD below mean value of W
MED_W = 0;   ! mean value of W
HIGH_W = 1;   ! +1 SD above mean value of W

LOW_Z = -1;   ! -1 SD below mean value of Z
MED_Z = 0;   ! mean value of Z
HIGH_Z = 1;   ! +1 SD above mean value of Z

! Calc conditional indirect effects for each combination of moderator values

ILOW_LOZ = a1*b1 + a4*b1*LOW_W + a5*b1*LOW_Z + a1*b4*LOW_W +
a4*b4*LOW_W*LOW_W + a5*b4*LOW_Z*LOW_W + a1*b5*LOW_Z +
a4*b5*LOW_W*LOW_Z + a5*b5*LOW_Z*LOW_Z;
IMEW_LOZ = a1*b1 + a4*b1*MED_W + a5*b1*LOW_Z + a1*b4*MED_W +
a4*b4*MED_W*MED_W + a5*b4*LOW_Z*MED_W + a1*b5*LOW_Z +
a4*b5*MED_W*LOW_Z + a5*b5*LOW_Z*LOW_Z;
IHIW_LOZ = a1*b1 + a4*b1*HIGH_W + a5*b1*LOW_Z + a1*b4*HIGH_W +
a4*b4*HIGH_W*HIGH_W + a5*b4*LOW_Z*HIGH_W + a1*b5*LOW_Z +
a4*b5*HIGH_W*LOW_Z + a5*b5*LOW_Z*LOW_Z;

ILOW_MEZ = a1*b1 + a4*b1*LOW_W + a5*b1*MED_Z + a1*b4*LOW_W +
a4*b4*LOW_W*LOW_W + a5*b4*MED_Z*LOW_W + a1*b5*MED_Z +
a4*b5*LOW_W*MED_Z + a5*b5*MED_Z*MED_Z;
IMEW_MEZ = a1*b1 + a4*b1*MED_W + a5*b1*MED_Z + a1*b4*MED_W +
a4*b4*MED_W*MED_W + a5*b4*MED_Z*MED_W + a1*b5*MED_Z +
a4*b5*MED_W*MED_Z + a5*b5*MED_Z*MED_Z;
IHIW_MEZ = a1*b1 + a4*b1*HIGH_W + a5*b1*MED_Z + a1*b4*HIGH_W +
a4*b4*HIGH_W*HIGH_W + a5*b4*MED_Z*HIGH_W + a1*b5*MED_Z +
a4*b5*HIGH_W*MED_Z + a5*b5*MED_Z*MED_Z;

ILOW_HIZ = a1*b1 + a4*b1*LOW_W + a5*b1*HIGH_Z + a1*b4*LOW_W +
a4*b4*LOW_W*LOW_W + a5*b4*HIGH_Z*LOW_W + a1*b5*HIGH_Z +
a4*b5*LOW_W*HIGH_Z + a5*b5*HIGH_Z*HIGH_Z;
IMEW_HIZ = a1*b1 + a4*b1*MED_W + a5*b1*HIGH_Z + a1*b4*MED_W +
a4*b4*MED_W*MED_W + a5*b4*HIGH_Z*MED_W + a1*b5*HIGH_Z +
a4*b5*MED_W*HIGH_Z + a5*b5*HIGH_Z*HIGH_Z;
IHIW_HIZ = a1*b1 + a4*b1*HIGH_W + a5*b1*HIGH_Z + a1*b4*HIGH_W +
a4*b4*HIGH_W*HIGH_W + a5*b4*HIGH_Z*HIGH_W + a1*b5*HIGH_Z +
a4*b5*HIGH_W*HIGH_Z + a5*b5*HIGH_Z*HIGH_Z;

! Calc conditional total effects for each combination of moderator values

TLOW_LOZ = ILOW_LOZ + cdash;
TMEW_LOZ = IMEW_LOZ + cdash;
THIW_LOZ = IHIW_LOZ + cdash;

TLOW_MEZ = ILOW_MEZ + cdash;
TMEW_MEZ = IMEW_MEZ + cdash;
THIW_MEZ = IHIW_MEZ + cdash;

TLOW_HIZ = ILOW_HIZ + cdash;
TMEW_HIZ = IMEW_HIZ + cdash;
THIW_HIZ = IHIW_HIZ + cdash;

! Use loop plot to plot conditional indirect effect of X on Y for each combination of low, med, high moderator values
! Could be edited to show conditional direct or conditional total effects instead
! NOTE - values from -3 to 3 in LOOP() statement since
! X is factor with mean set at default of 0

PLOT(PLOW_LOZ PMEW_LOZ PHIW_LOZ PLOW_MEZ PMEW_MEZ PHIW_MEZ
PLOW_HIZ PMEW_HIZ PHIW_HIZ);

LOOP(XVAL,-3,3,0.1);

PLOW_LOZ = ILOW_LOZ*XVAL;
PMEW_LOZ = IMEW_LOZ*XVAL;
PHIW_LOZ = IHIW_LOZ*XVAL;

PLOW_MEZ = ILOW_MEZ*XVAL;
PMEW_MEZ = IMEW_MEZ*XVAL;
PHIW_MEZ = IHIW_MEZ*XVAL;

PLOW_HIZ = ILOW_HIZ*XVAL;
PMEW_HIZ = IMEW_HIZ*XVAL;
PHIW_HIZ = IHIW_HIZ*XVAL;

PLOT:
TYPE = plot2;

OUTPUT:
CINT;