Mplus code for the mediation, moderation, and moderated mediation model templates from Andrew Hayes' PROCESS analysis examples

Model 6: 2 or more mediators (2 in this example), in series

Example Variables: 1 predictor X, 2 mediators M1 and M2, 1 outcome Y

Preliminary notes:

The code below assumes that

  • The primary IV (variable X) is continuous or dichotomous
  • Any moderators (variables W, V, Q, Z) are continuous, though the only adaptation required to handle dichotomous moderators is in the MODEL CONSTRAINT: and loop plot code - an example of how to do this is given in model 1b. Handling categorical moderators with > 2 categories is demonstrated in model 1d.
  • Any mediators (variable M, or M1, M2, etc.) are continuous and satisfy the assumptions of standard multiple regression. An example of how to handle a dichotomous mediator is given in model 4c.
  • The DV (variable Y) is continuous and satisfies the assumptions of standard multiple regression. An example of how to handle a dichotomous DV is given in model 1e (i.e. a moderated logistic regression) and in model 4d (i.e. an indirect effect in a logistic regression).

 

Model Diagram:

 

Statistical Diagram:

 

Model Equation(s):

Y = b0 + b1M1 + b2M2 + c'X
M1 = a01 + a1X
M2 = a02 + a2X + d1M1

 

Algebra to calculate total, indirect and/or conditional effects by writing model as Y = a + bX:

Y = b0 + b1M1 + b2M2 + c'X
M1 = a01 + a1X
M2 = a02 + a2X + d1M1


Hence... substituting in equations for M1 and M2

Y = b0 + b1(a01 + a1X) + b2(a02 + a2X + d1(a01 + a1X)) + c'X


Hence... multiplying out brackets

Y = b0 + a01b1 + a1b1X + a02b2 + a2b2X + a01d1b2 + a1d1b2X + c'X


Hence... grouping terms into form Y = a + bX

Y = (b0 + a01b1 + a02b2 + a01d1b2) + (a1b1 + a2b2 + a1d1b2 + c')X


Hence...

Three indirect effects of X on Y:

a1b1, a2b2, a1d1b2

One direct effect of X on Y:

c'

 

Mplus code for the model:

! Predictor variable - X
! Mediator variable(s) – M1, M2
! Moderator variable(s) - none
! Outcome variable - Y

USEVARIABLES = X M1 M2 Y;

ANALYSIS:
   TYPE = GENERAL;
   ESTIMATOR = ML;
   BOOTSTRAP = 10000;

! In model statement name each path using parentheses

MODEL:
   Y ON M1 (b1);
   Y ON M2 (b2);

   Y ON X (cdash);   ! direct effect of X on Y

   M1 ON X (a1);
   M2 ON X (a2);
   M2 ON M1 (d1);

! Use model constraint to calculate specific indirect paths and total indirect effect

MODEL CONSTRAINT:
   NEW(a1b1 a2b2 a1d1b2 TOTALIND TOTAL);
   a1b1 = a1*b1;   ! Specific indirect effect of X on Y via M1
   a2b2 = a2*b2;   ! Specific indirect effect of X on Y via M2
   a1d1b2 = a1*d1*b2;   ! Specific indirect effect of X on Y via M1 and M2
   TOTALIND = a1*b1 + a2*b2 + a1*d1*b2;   ! Total indirect effect of X on Y via M1, M2
   TOTAL = a1*b1 + a2*b2 + a1*d1*b2 + cdash;   ! Total effect of X on Y

OUTPUT:
   STAND CINT(bcbootstrap);

 

Editing required for testing indirect effect using alternative MODEL INDIRECT: subcommand

MODEL INDIRECT: offers an alternative to MODEL CONSTRAINT: for models containing indirect effects, where these are not moderated. To instead use MODEL INDIRECT: to test this model, you would edit the code above as follows:

First, you can remove the naming of parameters using parentheses in the MODEL: command, i.e. you just need:

MODEL:
   Y ON X M1 M2;
   M1 M2 ON X;
   M2 ON M1;

Second, replace the MODEL CONSTRAINT: subcommand with the following MODEL INDIRECT: subcommand:

   MODEL INDIRECT:
   Y IND M2 M1 X;

Leave the OUTPUT: command unchanged.

 

Return to Model Template index.

To cite this page and/or any code used, please use:
Stride, C.B., Gardner, S., Catley, N. & Thomas, F.(2015) 'Mplus code for the mediation, moderation, and moderated mediation model templates from Andrew Hayes' PROCESS analysis examples', http://www.offbeat.group.shef.ac.uk/FIO/mplusmedmod.htm

Home
Statistical Consultancy
Data Management
Public Training Courses
Inhouse & Bespoke Training
Links & Resources
About Us & Contact Details