Mplus code for the mediation, moderation, and moderated mediation model templates from Andrew Hayes' PROCESS analysis examples

Model 4: 1 or more mediators (2 in this example), in parallel if multiple [BASIC MEDIATION]

Example Variables: 1 predictor X, 2 mediators M1 and M2, 1 outcome Y

Preliminary notes:

The code below assumes that

  • The primary IV (variable X) is continuous or dichotomous
  • Any moderators (variables W,V,Q,Z) are continuous, though the only adaptation required to handle dichotomous moderators is in the MODEL CONSTRAINT: and loop plot code - an example of how to do this is given for model 1 (simple moderation)
  • Any mediators (variable M, or M1, M2, etc.) are assumed to be continuous
  • The DV (variable Y) is assumed to be continuous and to satisfy the assumptions of standard multiple regression - an example of how to handle a dichotomous DV is given for model 1 (i.e. a moderated logistic regression) and for this model at the bottom of the code (i.e. an indirect effect in a logistic regression).

Model Diagram:

 

Statistical Diagram:

 

Model Equation(s):

Y = b0 + b1M1 + b2M2 + c'X
M1 = a01 + a1X
M2 = a02 + a2X

 

Albegra to calculate total, indirect and/or conditional effects by writing model as Y = a + bX:

Y = b0 + b1M1 + b2M2 + c'X
M1 = a01 + a1X
M2 = a02 + a2X


Hence... substituting in equations for M1 and M2

Y = b0 + b1(a01 + a1X) + b2(a02 + a2X) + c'X


Hence... multiplying out brackets

Y = b0 + a01b1 + a1b1X + a02b2 + a2b2X + c'X


Hence... grouping terms into form Y = a + bX

Y = (b0 + a01b1 + a02b2) + (a1b1 + a2b2 + c')X


Hence...

Two indirect effects of X on Y:

a1b1, a2b2

One direct effect of X on Y:

c'

 

Mplus code for the model:

! Predictor variable - X
! Mediator variable(s) M1, M2
! Moderator variable(s) - none
! Outcome variable - Y

USEVARIABLES = X M1 M2 Y;

ANALYSIS:
   TYPE = GENERAL;
   ESTIMATOR = ML;
   BOOTSTRAP = 10000;

! In model statement name each path using parentheses

MODEL:
   Y ON M1 (b1);
   Y ON M2 (b2);

   Y ON X (cdash);   ! direct effect of X on Y

   M1 ON X (a1);
   M2 ON X (a2);

! Use model constraint to calculate specific indirect paths and total indirect effect

MODEL CONSTRAINT:
   NEW(a1b1 a2b2 TOTALIND TOTAL);
   a1b1 = a1*b1;   ! Specific indirect effect of X on Y via M1
   a2b2 = a2*b2;   ! Specific indirect effect of X on Y via M2
   TOTALIND = a1*b1 + a2*b2;   ! Total indirect effect of X on Y via M1, M2
   TOTAL = a1*b1 + a2*b2 + cdash;   ! Total effect of X on Y

OUTPUT:
   STAND CINT(bcbootstrap);

 

Editing required for testing indirect effect(s) using alternative MODEL INDIRECT: subcommand

MODEL INDIRECT: offers an alternative to MODEL CONSTRAINT: for models containing indirect effects, where these are not moderated. To use MODEL INDIRECT: instead, you would edit the code above as follows:

First, you can remove the naming of parameters using parentheses in the MODEL: command, i.e. you just need:

MODEL:
   Y ON X M1 M2;
   M1 M2 ON X;

Second, replace the MODEL CONSTRAINT: subcommand with the following MODEL INDIRECT: subcommand:

   MODEL INDIRECT:
   Y IND M1 X;
   Y IND M2 X;

Leave the OUTPUT: command unchanged.

 

Editing required for dichotomous DV scenario (logistic regression with an indirect effect)

Coming soon...

 

Return to Model Template index.

To cite this page and/or any code used, please use:
Stride, C.B., Gardner, S., Catley, N. & Thomas, F.(2015) 'Mplus code for the mediation, moderation, and moderated mediation model templates from Andrew Hayes' PROCESS analysis examples', http://www.offbeat.group.shef.ac.uk/FIO/mplusmedmod.htm

Home
Statistical Consultancy
Data Management
Public Training Courses
Inhouse & Bespoke Training
Links & Resources
About Us & Contact Details