Mplus code for mediation, moderation, and moderated mediation models

Model 22 (latent variable version): 1 or more mediators, in parallel if multiple (example uses 1), 2 moderators, 1 moderating the IV-Mediator path and direct IV-DV path, 1 moderating the Mediator-DV path

Example Variables: 1 latent predictor X measured by 4 observed variables X1-X4, 1 latent mediator M measured by 4 observed variables M1-M4, 2 latent moderators W and V, each measured by sets of 4 observed variables W1-W4 and V1-V4 respectively, 1 latent outcome Y measured by 4 observed variables Y1-Y4

Preliminary notes:

The code below assumes that

  • The latent IV (factor X) is measured by continuous observed variables X1-X4.
  • Any latent moderator(s) (factors W, V, Q, Z) are measured by continuous observed variables W1-W4, Z1-Z4, V1-V4, Q1-Q4 respectively.
  • Any latent mediator(s) (factor M, or factors M1, M2, etc.) are measured by continuous observed variables M1-M4 or M1_1-M1-4, M2_1-M2_4 respectively.
  • The latent outcome Y is measured by continuous observed variables Y1-Y4.

 

Model Diagram (factor indicator variables omitted for space/clarity reasons):

 

Statistical Diagram (factor indicator variables omitted for space/clarity reasons):

 

Model Equation(s):

Y = b0 + b1M + b2V + b3MV + c1'X + c2'W + c3'XW
M = a0 + a1X + a2W + a3XW

 

Algebra to calculate indirect and/or conditional effects by writing model as Y = a + bX:

Y = b0 + b1M + b2V + b3MV + c1'X + c2'W + c3'XW
M = a0 + a1X + a2W + a3XW


Hence... substituting in equation for M

Y = b0 + b1(a0 + a1X + a2W + a3XW) + b2V + b3(a0 + a1X + a2W + a3XW)V + c1'X + c2'W + c3'XW


Hence... multiplying out brackets

Y = b0 + a0b1 + a1b1X + a2b1W + a3b1XW + b2V + a0b3V + a1b3XV + a2b3VW + a3b3XWV + c1'X + c2'W + c3'XW


Hence... grouping terms into form Y = a + bX

Y = (b0 + a0b1 + a2b1W + b2V + a0b3V + a2b3VW + c2'W) + (a1b1 + a3b1W + a1b3V + a3b3WV + c1' + c3'W)X


Hence...

One indirect effect(s) of X on Y, conditional on W, V:

a1b1 + a3b1W + a1b3V + a3b3WV = (a1 + a3W)(b1 + b3V)

One direct effect of X on Y, conditional on W:

c1' + c3'W

 

Mplus code for the model:

! Latent predictor variable X measured by X1-X4
! Latent mediator M measured by 4 observed variables M1-M4
! Latent moderators W and V, each measured by sets of 4 observed variables W1-W4 and V1-V4 respectively
! Latent outcome variable Y measured by Y1-Y4

USEVARIABLES = X1 X2 X3 X4 M1 M2 M3 M4
W1 W2 W3 W4 V1 V2 V3 V4
Y1 Y2 Y3 Y4;

ANALYSIS:
   TYPE = GENERAL RANDOM;
   ESTIMATOR = ML;
   ALGORITHM = INTEGRATION;

! In model statement first state measurement model
! Then create any latent interactions required
! Then state structural model naming each path and intercept using parentheses

MODEL:

! Measurement model
! Identify moderator factors by fixing variance = 1 (instead of first loading)
! This makes these factors standardised
   X BY X1 X2 X3 X4;
   M BY M1 M2 M3 M4;
   W BY W1* W2 W3 W4;
   V BY V1* V2 V3 V4;
   Y BY Y1 Y2 Y3 Y4;

    W@1;   V@1;

! Create latent interactions
   MV | M XWITH V;
   XW | X XWITH W;

! Fit structural model and name parameters
! Note that intercepts of M, Y are fixed = 0 since they are latent vars
! so no code to state and name them as parameters
   Y ON M (b1);
   Y ON V (b2);
   Y ON MV (b3);

   Y ON X (cdash1);
   Y ON W (cdash2);
   Y ON XW (cdash3);

   M ON X (a1);
   M ON W (a2);
   M ON XW (a3);

! Use model constraint subcommand to test conditional indirect effects
! You need to pick low, medium and high moderator values for W, V
! for example, of 1 SD below mean, mean, 1 SD above mean

! 2 moderators, 3 values for each, gives 9 combinations
! arbitrary naming convention for conditional indirect and total effects used below:
! MEV_LOQ = medium value of V and low value of Q, etc.

MODEL CONSTRAINT:
    NEW(LOW_W MED_W HIGH_W LOW_V MED_V HIGH_V
    ILOW_LOV IMEW_LOV IHIW_LOV ILOW_MEV IMEW_MEV IHIW_MEV
    ILOW_HIV IMEW_HIV IHIW_HIV
    DIR_LOWW DIR_MEDW DIR_HIW
    TLOW_LOV TMEW_LOV THIW_LOV TLOW_MEV TMEW_MEV THIW_MEV
    TLOW_HIV TMEW_HIV THIW_HIV);

    LOW_W = -1;   ! -1 SD below mean value of W
    MED_W = 0;   ! mean value of W
    HIGH_W = 1;   ! +1 SD above mean value of W

    LOW_V = -1;   ! -1 SD below mean value of V
    MED_V = 0;   ! mean value of V
    HIGH_V = 1;   ! +1 SD above mean value of V

! Calc conditional indirect effects for each combination of moderator values

    ILOW_LOV = a1*b1 + a3*b1*LOW_W + a1*b3*LOW_V + a3*b3*LOW_W*LOW_V;
    IMEW_LOV = a1*b1 + a3*b1*MED_W + a1*b3*LOW_V + a3*b3*MED_W*LOW_V;
    IHIW_LOV = a1*b1 + a3*b1*HIGH_W + a1*b3*LOW_V + a3*b3*HIGH_W*LOW_V;

    ILOW_MEV = a1*b1 + a3*b1*LOW_W + a1*b3*MED_V + a3*b3*LOW_W*MED_V;
    IMEW_MEV = a1*b1 + a3*b1*MED_W + a1*b3*MED_V + a3*b3*MED_W*MED_V;
    IHIW_MEV = a1*b1 + a3*b1*HIGH_W + a1*b3*MED_V + a3*b3*HIGH_W*MED_V;

    ILOW_HIV = a1*b1 + a3*b1*LOW_W + a1*b3*HIGH_V + a3*b3*LOW_W*HIGH_V;
    IMEW_HIV = a1*b1 + a3*b1*MED_W + a1*b3*HIGH_V + a3*b3*MED_W*HIGH_V;
    IHIW_HIV = a1*b1 + a3*b1*HIGH_W + a1*b3*HIGH_V + a3*b3*HIGH_W*HIGH_V;

! Calc conditional direct effects for each combination of moderator values

    DIR_LOWW = cdash1 + cdash3*LOW_W;
    DIR_MEDW = cdash1 + cdash3*MED_W;
    DIR_HIW = cdash1 + cdash3*HIGH_W;

! Calc conditional total effects for each combination of moderator values

    TLOW_LOV = ILOW_LOV + DIR_LOWW;
    TMEW_LOV = IMEW_LOV + DIR_MEDW;
    THIW_LOV = IHIW_LOV + DIR_HIW;

    TLOW_MEV = ILOW_MEV + DIR_LOWW;
    TMEW_MEV = IMEW_MEV + DIR_MEDW;
    THIW_MEV = IHIW_MEV + DIR_HIW;

    TLOW_HIV = ILOW_HIV + DIR_LOWW;
    TMEW_HIV = IMEW_HIV + DIR_MEDW;
    THIW_HIV = IHIW_HIV + DIR_HIW;

! Use loop plot to plot conditional indirect effect of X on Y for each combination of low, med, high moderator values
! Could be edited to show conditional direct or conditional total effects instead
! NOTE - values from -3 to 3 in LOOP() statement since
! X is factor with mean set at default of 0

    PLOT(PLOW_LOV PMEW_LOV PHIW_LOV PLOW_MEV PMEW_MEV PHIW_MEV
    PLOW_HIV PMEW_HIV PHIW_HIV);

    LOOP(XVAL,-3,3,0.1);

    PLOW_LOV = ILOW_LOV*XVAL;
    PMEW_LOV = IMEW_LOV*XVAL;
    PHIW_LOV = IHIW_LOV*XVAL;

    PLOW_MEV = ILOW_MEV*XVAL;
    PMEW_MEV = IMEW_MEV*XVAL;
    PHIW_MEV = IHIW_MEV*XVAL;

    PLOW_HIV = ILOW_HIV*XVAL;
    PMEW_HIV = IMEW_HIV*XVAL;
    PHIW_HIV = IHIW_HIV*XVAL;

PLOT:
   TYPE = plot2;

OUTPUT:
   STAND CINT;

 

Return to Model Template index.

To cite this page and/or any code used, please use:
Stride C.B., Gardner S., Catley. N. & Thomas, F.(2015) 'Mplus code for the mediation, moderation, and moderated mediation model templates from Andrew Hayes' PROCESS analysis examples' , http://www.figureitout.org.uk

Home
Statistical Consultancy
Data Management
Public Training Courses
Inhouse & Bespoke Training
Links & Resources
About Us & Contact Details