Mplus code for mediation, moderation, and moderated mediation models

Model 15: 1 or more mediators, in parallel if multiple (example uses 1), 1 moderator of both Mediator-DV and direct IV-DV path

Example Variables: 1 predictor X, 1 mediator M, 1 moderator V, 1 outcome Y

Preliminary notes:

The code below assumes that

  • The primary IV (variable X) is continuous or dichotomous.
  • Any moderators (variables W, V, Q, Z) are continuous, though the only adaptation required to handle dichotomous moderators is in the MODEL CONSTRAINT: and loop plot code - an example of how to do this is given in model 1b. Handling categorical moderators with > 2 categories is demonstrated in model 1d.
  • Any mediators (variable M, or M1, M2, etc.) are continuous and satisfy the assumptions of standard multiple regression. An example of how to handle a dichotomous mediator is given in model 4c.
  • The DV (variable Y) is continuous and satisfies the assumptions of standard multiple regression - an example of how to handle a dichotomous DV is given in model 1e (i.e. a moderated logistic regression) and in model 4d (i.e. an indirect effect in a logistic regression).

 

Model Diagram:

 

Statistical Diagram:

 

Model Equation(s):

Y = b0 + b1M + b2MV + c1'X + c2'V + c3'XV
M = a0 + a1X

 

Algebra to calculate indirect and/or conditional effects by writing model as Y = a + bX:

Y = b0 + b1M + b2MV + c1'X + c2'V + c3'XV
M = a0 + a1X


Hence... substituting in equation for M

Y = b0 + b1(a0 + a1X) + b2(a0 + a1X)V + c1'X + c2'V + c3'XV


Hence... multiplying out brackets

Y = b0 + a0b1 + a1b1X + a0b2V + a1b2XV + c1'X + c2'V + c3'XV


Hence... grouping terms into form Y = a + bX

Y = (b0 + a0b1 + c2'V + a0b2V) + (a1b1 + a1b2V + c1' + c3'V)X


Hence...

One indirect effect(s) of X on Y, conditional on V:

a1b1 + a1b2V = a1(b1 + b2V)

One direct effect of X on Y, conditional on V:

c1' + c3'V

 

Mplus code for the model:

! Predictor variable - X
! Mediator variable(s) – M
! Moderator variable(s) – V
! Outcome variable - Y

USEVARIABLES = X M V Y MV XV;

! Create interaction terms
! Note that they have to be placed at end of USEVARIABLES subcommand above

DEFINE:
   MV = M*V;
   XV = X*V;

ANALYSIS:
   TYPE = GENERAL;
   ESTIMATOR = ML;
   BOOTSTRAP = 10000;

! In model statement name each path and intercept using parentheses

MODEL:
   [Y] (b0);
   Y ON M (b1);
   Y ON MV (b2);

   Y ON X (cdash1);
   Y ON V (cdash2);
   Y ON XV (cdash3);

   [M] (a0);
   M ON X (a1);

! Use model constraint subcommand to test conditional indirect effects
! You need to pick low, medium and high moderator values for V
! for example, of 1 SD below mean, mean, 1 SD above mean

! 1 moderator, 3 values for it
! arbitrary naming convention for conditional indirect and total effects used below:
! MED_Q = medium value of Q, etc.

MODEL CONSTRAINT:
    NEW(LOW_V MED_V HIGH_V
    IND_LOWV IND_MEDV IND_HIV
    IMM
    DIR_LOWV DIR_MEDV DIR_HIV
    TOT_LOWV TOT_MEDV TOT_HIV);

    LOW_V = #LOWV;   ! replace #LOWV in the code with your chosen low value of V
    MED_V = #MEDV;   ! replace #MEDV in the code with your chosen medium value of V
    HIGH_V = #HIGHV;   ! replace #HIGHV in the code with your chosen high value of V

! Calc conditional indirect effects for each combination of moderator values
! and index/indices of moderated mediation

    IND_LOWV = a1*b1 + a1*b2*LOW_V;
    IND_MEDV = a1*b1 + a1*b2*MED_V;
    IND_HIV = a1*b1 + a1*b2*HIGH_V;

    IMM = a1*b3;

! Calc conditional direct effects for each combination of moderator values

    DIR_LOWV = cdash1 + cdash3*LOW_V;
    DIR_MEDV = cdash1 + cdash3*MED_V;
    DIR_HIV = cdash1 + cdash3*HIGH_V;

! Calc conditional total effects for each combination of moderator values

    TOT_LOWV = IND_LOWV + DIR_LOWV;
    TOT_MEDV = IND_MEDV + DIR_MEDV;
    TOT_HIV = IND_HIV + DIR_HIV;

! Use loop plot to plot conditional indirect effect of X on Y for each combination of low, med, high moderator values
! Could be edited to show conditional direct or conditional total effects instead
! NOTE - values of 1,5 in LOOP() statement need to be replaced by
! logical min and max limits of predictor X used in analysis

    PLOT(LOMOD MEDMOD HIMOD);

    LOOP(XVAL,1,5,0.1);

    LOMOD = IND_LOWV*XVAL;
    MEDMOD = IND_MEDV*XVAL;
    HIMOD = IND_HIV*XVAL;

PLOT:
   TYPE = plot2;

OUTPUT:
   STAND CINT(bcbootstrap);

 

Return to Model Template index.

To cite this page and/or any code used, please use:
Stride C.B., Gardner S., Catley. N. & Thomas, F.(2015) 'Mplus code for the mediation, moderation, and moderated mediation model templates from Andrew Hayes' PROCESS analysis examples' , http://www.figureitout.org.uk

Home
Statistical Consultancy
Data Management
Public Training Courses
Inhouse & Bespoke Training
Links & Resources
About Us & Contact Details